' Name : emptygroups.vbs
' Description : script to enumerate all empty groups
' Author : dirk adamsky - deludi bv
' Version : 1.00
' Date : 18-03-2010
' Level : intermediate

Set objCommand = CreateObject("ADODB.Command")
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
objCommand.ActiveConnection = objConnection

Set objRootDSE = GetObject("LDAP://RootDSE")
strBase = "<LDAP://" & objRootDSE.Get("defaultNamingContext") & ">"
Set objRootDSE = Nothing

strFilter = "(&(objectCategory=group)(!member=*))"
strAttributes = "name"
strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"
objCommand.CommandText = strQuery
objCommand.Properties("Page Size") = 100
objCommand.Properties("Timeout") = 30
objCommand.Properties("Cache Results") = False

Set objRecordSet = objCommand.Execute
Do Until objRecordSet.EOF
	Wscript.Echo objRecordSet.Fields("name").Value
	objRecordSet.MoveNext
Loop

objRecordSet.Close
objConnection.Close

Set objRecordSet = Nothing
Set objConnection = Nothing
Set objCommand = Nothing

7 Responses so far.

1. Cold Fusion Authorize.net Script | ColdFusion WebDev Insider says:

   31 March 2010 at 12:45

   [...] Active Directory: VBscript to enumerate all empty groups | Dirk … [...]

   Reply
2. Aman says:

   23 June 2011 at 16:09

   Thanks for the script. But, how can I get all the empty groups and their descriptions ?

   Reply
3. dirk adamsky says:

   23 June 2011 at 18:16

   Hi Aman,

   I have an updated version for you:

   Set objCommand = CreateObject("ADODB.Command")
   Set objConnection = CreateObject("ADODB.Connection")
   objConnection.Provider = "ADsDSOObject"
   objConnection.Open "Active Directory Provider"
   objCommand.ActiveConnection = objConnection
   
   Set objRootDSE = GetObject("LDAP://RootDSE")
   strBase = "<LDAP://" & objRootDSE.Get("defaultNamingContext") & ">"
   Set objRootDSE = Nothing
   
   strFilter = "(&(objectCategory=group)(!member=*))"
   strAttributes = "name, description"
   strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"
   objCommand.CommandText = strQuery
   objCommand.Properties("Page Size") = 100
   objCommand.Properties("Timeout") = 30
   objCommand.Properties("Cache Results") = False
   
   Set objRecordSet = objCommand.Execute
   Do Until objRecordSet.EOF
   	Wscript.Echo objRecordSet.Fields("name").Value & " ; " & objRecordSet.Fields("description").Value
   	objRecordSet.MoveNext
   Loop
   
   objRecordSet.Close
   objConnection.Close
   
   Set objRecordSet = Nothing
   Set objConnection = Nothing
   Set objCommand = Nothing
   

   Dirk Adamsky

   Reply
   • Ryan says:

     1 September 2011 at 14:30

     Hi,

     I work for a Large international company. Our sites are broken up into facilitoes. Ho can i get this to run on just one OU.

     EG: OU=Groups00,OU=Groups,OU=TIL,OU=Europe,OU=CompanyName,DC=ct,DC=Company,DC=netTh
     Thanks
     Ryan

     Reply
4. dirk adamsky says:

   1 September 2011 at 14:48

   Hi Ryan,

   Here’s an example script that runs on one OU.

   Set objCommand = CreateObject("ADODB.Command")
   Set objConnection = CreateObject("ADODB.Connection")
   objConnection.Provider = "ADsDSOObject"
   objConnection.Open "Active Directory Provider"
   objCommand.ActiveConnection = objConnection
   
   strBase = "<LDAP://OU=test,DC=test,DC=org>"
   
   strFilter = "(&(objectCategory=group)(!member=*))"
   strAttributes = "name, description"
   strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"
   objCommand.CommandText = strQuery
   objCommand.Properties("Page Size") = 100
   objCommand.Properties("Timeout") = 30
   objCommand.Properties("Cache Results") = False
   
   Set objRecordSet = objCommand.Execute
   Do Until objRecordSet.EOF
   	Wscript.Echo objRecordSet.Fields("name").Value & " ; " & objRecordSet.Fields("description").Value
   	objRecordSet.MoveNext
   Loop
   
   objRecordSet.Close
   objConnection.Close
   
   Set objRecordSet = Nothing
   Set objConnection = Nothing
   Set objCommand = Nothing
   

   Please change the value for strBase to your desired OU.

   Best regards,

   Dirk Adamsky

   Reply
   • Ryan says:

     1 September 2011 at 15:59

     Hi,

     Giving me error: Line 19, Char:2 Error: Mismatch, Code 800A000D, Source MS VBScript Runtime Error.

     Any tips,

     Thanks

     Reply
5. dirk adamsky says:

   6 September 2011 at 15:19

   Hi Ryan,

   1. Can you check your copy of the script for typos?
   2. Do you use query based distribution groups?

   Best regards,

   dirk adamsky

   Reply